OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	05/09/2024 07:14:16 AM	rwxr-xr-x
📁 alloc	-	05/09/2024 07:14:16 AM	rwxr-xr-x
📄 check_bq27xxx_data.cocci	3.42 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 d_find_alias.cocci	1.28 KB	01/28/2018 09:20:33 PM	rw-r--r--
📁 debugfs	-	05/09/2024 07:14:16 AM	rwxr-xr-x
📄 drm-get-put.cocci	1.93 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 err_cast.cocci	1.07 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 kstrdup.cocci	2.4 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 memdup.cocci	1.35 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 memdup_user.cocci	1.28 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 platform_no_drv_owner.cocci	3.78 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 pm_runtime.cocci	2.34 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 ptr_ret.cocci	1.77 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 resource_size.cocci	2.07 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 simple_open.cocci	1.21 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 stream_open.cocci	7.6 KB	06/16/2023 05:32:39 PM	rw-r--r--
📄 vma_pages.cocci	1.48 KB	01/28/2018 09:20:33 PM	rw-r--r--

Editing: ptr_ret.cocci

///
/// Use PTR_ERR_OR_ZERO rather than if(IS_ERR(...)) + PTR_ERR
///
// Confidence: High
// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6.  GPLv2.
// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6.  GPLv2.
// URL: http://coccinelle.lip6.fr/
// Options: --no-includes --include-headers
//
// Keywords: ERR_PTR, PTR_ERR, PTR_ERR_OR_ZERO
// Version min: 2.6.39
//

virtual context
virtual patch
virtual org
virtual report

@depends on patch@
expression ptr;
@@

- if (IS_ERR(ptr)) return PTR_ERR(ptr); else return 0;
+ return PTR_ERR_OR_ZERO(ptr);

@depends on patch@
expression ptr;
@@

- if (IS_ERR(ptr)) return PTR_ERR(ptr); return 0;
+ return PTR_ERR_OR_ZERO(ptr);

@depends on patch@
expression ptr;
@@

- (IS_ERR(ptr) ? PTR_ERR(ptr) : 0)
+ PTR_ERR_OR_ZERO(ptr)

@r1 depends on !patch@
expression ptr;
position p1;
@@

* if@p1 (IS_ERR(ptr)) return PTR_ERR(ptr); else return 0;

@r2 depends on !patch@
expression ptr;
position p2;
@@

* if@p2 (IS_ERR(ptr)) return PTR_ERR(ptr); return 0;

@r3 depends on !patch@
expression ptr;
position p3;
@@

* IS_ERR@p3(ptr) ? PTR_ERR(ptr) : 0

@script:python depends on org@
p << r1.p1;
@@

coccilib.org.print_todo(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")

@script:python depends on org@
p << r2.p2;
@@

coccilib.org.print_todo(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")

@script:python depends on org@
p << r3.p3;
@@

coccilib.org.print_todo(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")

@script:python depends on report@
p << r1.p1;
@@

coccilib.report.print_report(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")

@script:python depends on report@
p << r2.p2;
@@

coccilib.report.print_report(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")

@script:python depends on report@
p << r3.p3;
@@

coccilib.report.print_report(p[0], "WARNING: PTR_ERR_OR_ZERO can be used")