OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	11/17/2022 06:42:18 AM	rwxr-xr-x
📄 clk_put.cocci	1.23 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 devm_free.cocci	2.01 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 ifnullfree.cocci	1.26 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 iounmap.cocci	1.25 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 kfree.cocci	1.77 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 kfreeaddr.cocci	583 bytes	01/28/2018 09:20:33 PM	rw-r--r--
📄 pci_free_consistent.cocci	1.22 KB	01/28/2018 09:20:33 PM	rw-r--r--

Editing: iounmap.cocci

/// Find missing iounmaps.
///
//# This only signals a missing iounmap when there is an iounmap later
//# in the same function.
//# False positives can be due to loops.
//
// Confidence: Moderate
// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6.  GPLv2.
// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6.  GPLv2.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options:

virtual context
virtual org
virtual report

@iom@
expression e;
statement S,S1;
int ret;
position p1,p2,p3;
@@

e = \(ioremap@p1\|ioremap_nocache@p1\)(...)
... when != iounmap(e)
if (<+...e...+>) S
... when any
    when != iounmap(e)
    when != if (...) { ... iounmap(e); ... }
(
 if (ret == 0) S1
|
if (...)
   { ...
     return 0; }
|
if (...)
   { ...
     return <+...e...+>; }
|
*if@p2 (...)
   { ... when != iounmap(e)
         when forall
     return@p3 ...; }
)
... when any
iounmap(e);

@script:python depends on org@
p1 << iom.p1;
p2 << iom.p2;
p3 << iom.p3;
@@

cocci.print_main("ioremap",p1)
cocci.print_secs("if",p2)
cocci.print_secs("needed iounmap",p3)

@script:python depends on report@
p1 << iom.p1;
p2 << iom.p2;
p3 << iom.p3;
@@

msg = "ERROR: missing iounmap; ioremap on line %s and execution via conditional on line %s" % (p1[0].line,p2[0].line)
coccilib.report.print_report(p3[0],msg)