OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	11/17/2022 06:42:18 AM	rwxr-xr-x
📁 alloc	-	11/17/2022 06:42:23 AM	rwxr-xr-x
📄 check_bq27xxx_data.cocci	3.42 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 d_find_alias.cocci	1.28 KB	01/28/2018 09:20:33 PM	rw-r--r--
📁 debugfs	-	11/17/2022 06:42:23 AM	rwxr-xr-x
📄 drm-get-put.cocci	1.93 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 err_cast.cocci	1.07 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 kstrdup.cocci	2.4 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 memdup.cocci	1.35 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 memdup_user.cocci	1.28 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 platform_no_drv_owner.cocci	3.78 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 pm_runtime.cocci	2.34 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 ptr_ret.cocci	1.77 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 resource_size.cocci	2.07 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 simple_open.cocci	1.21 KB	01/28/2018 09:20:33 PM	rw-r--r--
📄 stream_open.cocci	7.6 KB	11/01/2022 04:52:05 PM	rw-r--r--
📄 vma_pages.cocci	1.48 KB	01/28/2018 09:20:33 PM	rw-r--r--

Editing: memdup_user.cocci

/// Use memdup_user rather than duplicating its implementation
/// This is a little bit restricted to reduce false positives
///
// Confidence: High
// Copyright: (C) 2010-2012 Nicolas Palix.  GPLv2.
// Copyright: (C) 2010-2012 Julia Lawall, INRIA/LIP6.  GPLv2.
// Copyright: (C) 2010-2012 Gilles Muller, INRIA/LiP6.  GPLv2.
// URL: http://coccinelle.lip6.fr/
// Comments:
// Options: --no-includes --include-headers

virtual patch
virtual context
virtual org
virtual report

@depends on patch@
expression from,to,size;
identifier l1,l2;
@@

-  to = \(kmalloc\|kzalloc\)(size,GFP_KERNEL);
+  to = memdup_user(from,size);
   if (
-      to==NULL
+      IS_ERR(to)
                 || ...) {
   <+... when != goto l1;
-  -ENOMEM
+  PTR_ERR(to)
   ...+>
   }
-  if (copy_from_user(to, from, size) != 0) {
-    <+... when != goto l2;
-    -EFAULT
-    ...+>
-  }

@r depends on !patch@
expression from,to,size;
position p;
statement S1,S2;
@@

*  to = \(kmalloc@p\|kzalloc@p\)(size,GFP_KERNEL);
   if (to==NULL || ...) S1
   if (copy_from_user(to, from, size) != 0)
   S2

@script:python depends on org@
p << r.p;
@@

coccilib.org.print_todo(p[0], "WARNING opportunity for memdup_user")

@script:python depends on report@
p << r.p;
@@

coccilib.report.print_report(p[0], "WARNING opportunity for memdup_user")