OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	06/06/2024 02:31:58 PM	rwxr-xr-x
📄 _bootctl	1.04 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _busctl	3 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _hostnamectl	2.17 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _journalctl	4.76 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _localectl	3.46 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _loginctl	5.63 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _sd_hosts_or_user_at_host	79 bytes	03/03/2023 04:27:39 AM	rw-r--r--
📄 _sd_outputmodes	202 bytes	03/03/2023 04:27:39 AM	rw-r--r--
📄 _sd_unit_files	226 bytes	03/03/2023 04:27:39 AM	rw-r--r--
📄 _snap	1.75 KB	06/04/2024 10:58:39 PM	rw-r--r--
📄 _systemctl	14.39 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd	3.71 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd-analyze	2.34 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd-delta	527 bytes	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd-inhibit	1 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd-run	3.01 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _systemd-tmpfiles	699 bytes	03/03/2023 04:27:39 AM	rw-r--r--
📄 _timedatectl	1.96 KB	03/03/2023 04:27:39 AM	rw-r--r--
📄 _udevadm	5.82 KB	03/03/2023 04:27:39 AM	rw-r--r--

Editing: _timedatectl

#compdef timedatectl

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'