OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	10/21/2019 03:48:26 PM	rwxr-xr-x
📄 _bootctl	1.08 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _busctl	3.03 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _curl	12.55 KB	03/15/2023 12:58:03 PM	rw-r--r--
📄 _hostnamectl	2.22 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _journalctl	5.83 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _kernel-install	651 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _localectl	3.5 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _loginctl	5.67 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _networkctl	1.21 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _ninja	2.23 KB	09/11/2017 01:20:10 AM	rw-r--r--
📄 _sd_hosts_or_user_at_host	116 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _sd_outputmodes	279 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _sd_unit_files	255 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _snap	1.75 KB	12/01/2022 08:52:23 AM	rw-r--r--
📄 _systemctl	14.72 KB	03/02/2023 12:58:02 PM	rw-r--r--
📄 _systemd	3.75 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-analyze	2.84 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-delta	564 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-inhibit	1.04 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-resolve	2.32 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-run	3.06 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _systemd-tmpfiles	736 bytes	01/28/2018 03:58:17 PM	rw-r--r--
📄 _timedatectl	1.99 KB	01/28/2018 03:58:17 PM	rw-r--r--
📄 _udevadm	5.86 KB	01/28/2018 03:58:17 PM	rw-r--r--

Editing: _timedatectl

#compdef timedatectl
# SPDX-License-Identifier: LGPL-2.1+

_timedatectl_set-timezone(){
    local -a _timezones
    _timezones=( ${(f)"$(_call_program timezones "${service}" list-timezones)"} )
    compadd "$_timezones[@]"
}

_timedatectl_set-time(){
    _message "YYYY-MM-DD HH:MM:SS"
}

_timedatectl_set-local-rtc(){
    local -a _options
    _options=(
        '0:Maintain RTC in universal time'
        '1:Maintain RTC in local time'
    )
    _describe options _options
}

_timedatectl_set-ntp(){
    local -a _options
    _options=(
        '0:Disable NTP based network time configuration'
        '1:Enable NTP based network time configuration'
    )
    _describe options _options
}

_timedatectl_command(){
    local -a _timedatectl_cmds
    _timedatectl_cmds=(
        'status:Show current time settings'
        'set-time:Set system time'
        'set-timezone:Set system timezone'
        'list-timezones:Show known timezones'
        'set-local-rtc:Control whether RTC is in local time'
        'set-ntp:Control whether NTP is enabled'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'timedatectl command' _timedatectl_cmds
    else
        local curcontext="$curcontext"
        cmd="${${_timedatectl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd )); then
            if (( $+functions[_timedatectl_$cmd] )); then
                _timedatectl_$cmd
            else
                _message "no more options"
            fi
        else
            _message "unknown timedatectl command: $words[1]"
        fi
    fi
}

_arguments -s \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--adjust-system-clock[Adjust system clock when changing local RTC mode]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-ask-password[Do not prompt for password]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
    '*::timedatectl commands:_timedatectl_command'